File:Lorentz transform of E.gif
Summary
| Description |
English: If you look at a constant electrostatic field from a moving frame of reference you will see a magnetic field appearing when v is comparable to c, due to the fact that the electromagnetic vector potential transform as a 4-vector. |
| Date | |
| Source | https://twitter.com/j_bertolotti/status/1130504648366972930 |
| Author | Jacopo Bertolotti |
| Permission (Reusing this file) |
https://twitter.com/j_bertolotti/status/1030470604418428929 |
Mathematica 11.0 code
c = 1;
\[Gamma][\[Beta]_] := 1/Sqrt[1 - \[Beta]^2];
L[\[Beta]_] := {{\[Gamma][\[Beta]], 0, 0, - \[Beta] \[Gamma][\[Beta]]},
{0, 1, 0, 0},
{0, 0, 1, 0},
{- \[Beta] \[Gamma][\[Beta]], 0, 0, \[Gamma][\[Beta]]}
};
E0 = {0, 0, 1};
B0 = {0, 0, 0};
F0 = {
{0, -B0[[3]], B0[[2]], E0[[1]]/c},
{B0[[3]], 0, -B0[[1]], E0[[2]]/c},
{-B0[[2]], B0[[1]], 0, E0[[3]]/c},
{-E0[[1]]/c, -E0[[2]]/c, -E0[[3]]/c, 0}
};
F1[\[Beta]_] := L[\[Beta]].F0.L[\[Beta]];
E1[\[Beta]_] := F1[\[Beta]][[1 ;; 3, 4]];
B1[\[Beta]_] := {F1[\[Beta]][[3, 2]], F1[\[Beta]][[1, 3]], F1[\[Beta]][[2, 1]]};
p1 = Table[
Graphics3D[{Thick, Black, Arrowheads[Min[Norm[E1[\[Beta]]]/30, 0.05]], Arrow[{{0, 0, 0}, E1[\[Beta]]}], Text[Style["E", Bold, FontSize -> 12], {E1[\[Beta]] + {0, 0.2, 0}}],
Arrowheads[Min[Norm[B1[\[Beta]]]/30, 0.05]], Red, Arrow[{{0, 0, 0}, B1[\[Beta]]}], Text[Style["B", Bold, FontSize -> 12], {B1[\[Beta]] + {0.2, 0, 0.2}}],
Blue, Arrowheads[Min[\[Beta]/10, 0.05]], Arrow[{{0, 0, 0}, {3*\[Beta], 0, 0}}], Text[Style["v", Bold, FontSize -> 12], {3*\[Beta] + 0.1, 0, -0.2}]
}, PlotRange -> {{-3, 3}, {-3, 3}, {-3, 3}},
PlotLabel ->
Style[StringForm["v\!\(\*SubscriptBox[\(=\), \(``\)]\)c", N[\[Beta], 3], \[Tau]], Medium, FontFamily -> "DejaVu Serif"], LabelStyle -> {Black, Bold}, Boxed -> False]
, {\[Beta], 0, 0.945, 0.01}];
ListAnimate[p1]
Licensing
I, the copyright holder of this work, hereby publish it under the following license:
  |
This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. |
| The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
|
