File:Resonant tunneling.gif
Summary
| Description |
English: n QM there is a small probability that a particle can tunnel through a barrier. But if there are two barriers at the right spacing from each other, the probability to tunnel through both can be quite large. |
| Date | |
| Source | https://twitter.com/j_bertolotti/status/1177578685311913984 |
| Author | Jacopo Bertolotti |
| Permission (Reusing this file) |
https://twitter.com/j_bertolotti/status/1030470604418428929 |
Mathematica 11.0 code
en = 0.5; (*energy of the incident particle (both mass and h/2\[Pi] are set to 1*)
a = 1; (* amplitude of the incident wavefunction (as we need to divide all of our results by this it is easier to just set it to 1)*)
b1h = 1; (*height of the first barrier*)
b2h = 1; (*height of the second barrier*)
b11 = 10; (*initial position of the first barrier*)
b12 = 11; (*end of the first barrier*)
p1 = Table[
b21 = 11 + \[Epsilon]; (*the position of the second barrier is moved gradually*)
b22 = 12 + \[Epsilon];
sol = Solve[{
a E^(I Sqrt[2 (en)] b11) + b E^(-I Sqrt[2 (en)] b11) == c E^(I Sqrt[2 (en - b1h)] b11) + d E^(-I Sqrt[2 (en - b1h)] b11),
c E^(I Sqrt[2 (en - b1h)] b12) + d E^(-I Sqrt[2 (en - b1h)] b12) == e E^(I Sqrt[2 (en)] b12) + f E^(-I Sqrt[2 (en)] b12),
e E^(I Sqrt[2 (en)] b21) + f E^(-I Sqrt[2 (en)] b21) == g E^(I Sqrt[2 (en - b2h)] b21) + h E^(-I Sqrt[2 (en - b2h)] b21),
g E^(I Sqrt[2 (en - b2h)] b22) + h E^(-I Sqrt[2 (en - b2h)] b22) == i E^(I Sqrt[2 (en)] b22),
a I Sqrt[2 (en)] E^(I Sqrt[2 (en)] b11) - b I Sqrt[2 (en)] E^(-I Sqrt[2 (en)] b11) == c I Sqrt[2 (en - b1h)] E^(I Sqrt[2 (en - b1h)] b11) - d I Sqrt[2 (en - b1h)] E^(-I Sqrt[2 (en - b1h)] b11),
c I Sqrt[2 (en - b1h)] E^(I Sqrt[2 (en - b1h)] b12) - d I Sqrt[2 (en - b1h)] E^(-I Sqrt[2 (en - b1h)] b12) == e I Sqrt[2 (en)] E^(I Sqrt[2 (en)] b12) - f I Sqrt[2 (en)] E^(-I Sqrt[2 (en)] b12),
e I Sqrt[2 (en)] E^(I Sqrt[2 (en)] b21) - f I Sqrt[2 (en)] E^(-I Sqrt[2 (en)] b21) == g I Sqrt[2 (en - b1h)] E^(I Sqrt[2 (en - b2h)] b21) - h I Sqrt[2 (en - b1h)] E^(-I Sqrt[2 (en - b2h)] b21),
g I Sqrt[2 (en - b1h)] E^(I Sqrt[2 (en - b2h)] b22) - h I Sqrt[2 (en - b1h)] E^(-I Sqrt[2 (en - b2h)] b22) == i I Sqrt[2 (en)] E^(I Sqrt[2 (en)] b22)}, {b, c, d, e, f, g, h, i}]; (*impose that the wavefunction and its derivative is continuous at each interface*)
\[Psi] = Piecewise[{{a E^(I Sqrt[2 (en)] x) + b E^(-I Sqrt[2 (en)] x), x < b11}, {c E^(I Sqrt[2 (en - b1h)] x) + d E^(-I Sqrt[2 (en - b1h)] x), b11 < x < b12}, {e E^(I Sqrt[2 (en)] x) + f E^(-I Sqrt[2 (en)] x), b12 < x < b21}, {g E^(I Sqrt[2 (en - b2h)] x) + h E^(-I Sqrt[2 (en - b2h)] x), b21 < x < b22}, {i E^(I Sqrt[2 (en)] x), x > b22}}] /. sol;
V = Piecewise[{{0, x < b11}, {b1h, b11 < x < b12}, {0, b12 < x < b21}, {b2h, b21 < x < b22}, {0, x > b22}}];
Plot[{Abs[\[Psi]]^2/3, V, Re[\[Psi]]/3}, {x, 0, 25}, PlotRange -> {-1, 2.5}, PlotStyle -> {Black, Directive[Red], Directive[Blue]}, Filling -> {2 -> Axis}, Axes -> False, PlotLegends -> {"|\[Psi]\!\(\*SuperscriptBox[\(|\), \(2\)]\)", "V", "Re[\[Psi]]"}]
, {\[Epsilon], 0.5, 5.2, 0.05}];
ListAnimate[p1]
Licensing
I, the copyright holder of this work, hereby publish it under the following license:
  |
This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. |
| The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
|
