# Copia de http://gnuplot.sourceforge.net/demo/enhanced_utf8.html
#
# Test page for enhanced text mode in UTF-8 encoding
#
# Suggested PostScript font test
# set fontpath "/usr/local/share/fonts"
# set term post color adobeglyphnames fontfile 'l_10646.ttf' font "LucidaSansUnicode,12"
#set output 'enhanced_utf8.ps'
#
set terminal png enhanced
#set termoption enhanced
#save_encoding = GPVAL_ENCODING
set encoding utf8
set output 'gnuplot-ayuda5.png'
#
set title "Ejemplos de aplicación del modo 'enhanced text' usando codificación simple UTF-8\nExiste otra página que muestra como usar tipos de codificación separados"
set xrange [-1:1]
set yrange [-0.5:1.1]
set format xy "%.1f"
set arrow from  0.5, -0.5 to  0.5, 0.0 nohead
#
set label 1 at -0.65, 0.95
set label 1 "Superíndice y subíndice:" tc lt 3

set label 3 at -0.55, 0.85
set label 3 'A_{j,k} 10^{-2}  x@^2_k    x@_0^{-3/2}y'

set label 5 at -0.55,  0.7 
set label 5 "Comodínes:" tc lt 3
set label 6 at -0.45, 0.6 
set label 6 "<&{{/=20 B}ig}> <&{x@_0^{-3/2}y}> reserva espacio para"
set label 7 at -0.45, 0.5 
set label 7 "<{{/=20 B}ig}> <{x@_0^{-3/2}y}>"

set label 8 at -0.9, -0.2
set label 8 "Re-impresión\n(v debería aparecer sobre d)" tc lt 3
set label 9 at -0.85, -0.4
set label 9 " ~{abcdefg}{0.8v}"


set label 10 at  -.40, 0.35
set label 10 "UTF-8 no requiere símbolos especiales:" tc lt 3
set label 11 at -.30, 0.2
set label 11 "{/*1.5 ∫@_{/=9.6 0}^{/=12 ∞}} {e^{-{μ}^2/2} d}{μ=(π/2)^{1/2}}"

set label 21 at 0.5, -.1
set label 21 "Izq. ^{centrado} ƒ(αβγδεζ)" left
set label 22 at 0.5, -.2
set label 22 "Der. ^{centrado} ƒ(αβγδεζ)" right
set label 23 at 0.5, -.3
set label 23 "Centr. ^{centrado} ƒ(αβγδεζ)" center

set label 30 at -.9, 0.0 "{/:Bold Negrilla} y {/:Italic Cursiva} markup"

set key title " "
plot sin(x)**2 lt 2 lw 2 title "sin^2(x)"